+Show TOC
×Hide TOC

UniqueList

Kind of class:	public class
Package:	org.casalib.collection
Inherits from:	List
Version:	04/27/08
Author:	Aaron Clinger
Classpath:	org.casalib.collection.UniqueList
File last modified:	Sunday, 28 March 2010, 11:55:54

► View source

▼ Hide source

/*
    CASA Lib for ActionScript 3.0
    Copyright (c) 2010, Aaron Clinger & Contributors of CASA Lib
    All rights reserved.
    
    Redistribution and use in source and binary forms, with or without
    modification, are permitted provided that the following conditions are met:
    
    - Redistributions of source code must retain the above copyright notice,
      this list of conditions and the following disclaimer.
    
    - Redistributions in binary form must reproduce the above copyright notice,
      this list of conditions and the following disclaimer in the documentation
      and/or other materials provided with the distribution.
    
    - Neither the name of the CASA Lib nor the names of its contributors
      may be used to endorse or promote products derived from this software
      without specific prior written permission.
    
    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
    POSSIBILITY OF SUCH DAMAGE.
*/
package org.casalib.collection {
    import org.casalib.collection.List;
    import org.casalib.util.ArrayUtil;
    
    /**
        An ordered or sequence collection that contains no duplicates. Similar to Java's Set but contains all the methods of List.
        
        @author Aaron Clinger
        @version 04/27/08
        @see List
    */
    public class UniqueList extends List {
        
        
        /**
            Creates a new UniqueList;
            
            @param collection: An Array of items to populate the contents of this list; UniqueList will only accept the unique elements of the Array.
        */
        public function UniqueList(collection:Array = null) {
            super((collection == null) ? null : ArrayUtil.removeDuplicates(collection));
        }
        
        /**
            {@inheritDoc}
            
            @param item: {@inheritDoc}
            @return Returns <code>true</code> if the element was unique and added; otherwise <code>false</code>.
        */
        override public function addItem(item:*):Boolean {
            if (this.contains(item))
                return false;
            
            this._collection.push(item);
            
            return true;
        }
        
        /**
            {@inheritDoc}
            
            @param item: {@inheritDoc}
            @param index: {@inheritDoc}
            @return Returns <code>true</code> if the element was unique and added; otherwise <code>false</code>.
        */
        override public function addItemAt(item:*, index:int):Boolean {
            if (this.contains(item))
                return false;
            
            this._collection.splice(index, 0, item);
            
            return true;
        }
        
        /**
            Modifies original list by adding all the elements from another list that aren't already present.
            
            @param items: {@inheritDoc}
            @return Returns <code>true</code> if any elements of the specified list were unique and added; otherwise <code>false</code>.
        */
        override public function addItems(items:IList):Boolean {
            var uniqueItems:Array = items.toArray();
            
            ArrayUtil.removeItems(uniqueItems, this.toArray());
            
            if (uniqueItems.length == 0)
                return false;
            
            this._collection = this._collection.concat(uniqueItems);
            
            return true;
        }
        
        /**
            Modifies original list by adding all the elements from another list, that aren't already present, at a specified position.
            
            @param items: {@inheritDoc}
            @param index: {@inheritDoc}
            @return Returns <code>true</code> if any elements of the specified list were unique and added; otherwise <code>false</code>.
        */
        override public function addItemsAt(items:IList, index:int = 0x7fffffff):Boolean {
            var uniqueItems:Array = items.toArray();
            
            ArrayUtil.removeItems(uniqueItems, this.toArray());
            
            if (uniqueItems.length == 0)
                return false;
            
            return ArrayUtil.addItemsAt(this._collection, uniqueItems, index);
        }
        
        /**
            {@inheritDoc}
            
            @param item: {@inheritDoc}
            @param index: {@inheritDoc}
            @return {@inheritDoc}
            @throws Error if you try to set an item that is already contained in the list.
        */
        override public function setItem(item:*, index:int):* {
            if (this.contains(item))
                throw new Error('List already contains specified item (' + item + ').');
            
            return this._collection.splice(index, 1, item)[0];
        }
        
        /**
            {@inheritDoc}
            
            @param startIndex: {@inheritDoc}
            @param endIndex: {@inheritDoc}
            @return {@inheritDoc}
        */
        override public function subList(startIndex:int = 0, endIndex:int = 16777215):IList {
            return new UniqueList(this._collection.slice(startIndex, endIndex));
        }
        
        /**
            {@inheritDoc}
            
            @return {@inheritDoc}
        */
        override public function clone():IList {
            return new UniqueList(this.toArray());
        }
    }
}

An ordered or sequence collection that contains no duplicates. Similar to Java's Set but contains all the methods of List.

Summary

Constructor

UniqueList (collection:Array = null)
- Creates a new UniqueList;

Instance properties

Instance properties inherited from List

_collection size

Instance methods

addItem (item:*) : Boolean
- Appends the specified item to the end of this list.
addItemAt (item:*, index:int) : Boolean
- Inserts an item as a specified position.
addItems (items:IList) : Boolean
- Modifies original list by adding all the elements from another list that aren't already present.
addItemsAt (items:IList, index:int = 0x7fffffff) : Boolean
- Modifies original list by adding all the elements from another list, that aren't already present, at a specified position.
setItem (item:*, index:int) : *
- Replaces an item at a specified position.
subList (startIndex:int = 0, endIndex:int = 16777215) : IList
- Returns a portion of this list.
clone : IList
- Returns a list that is an exact copy of the original list.

Instance methods inherited from List

Constructor

UniqueList

public function UniqueList (

collection:Array = null)

Creates a new UniqueList;

Parameters:

collection:

An Array of items to populate the contents of this list; UniqueList will only accept the unique elements of the Array.

Instance methods

addItem

override public function addItem (

item:*) : Boolean

Appends the specified item to the end of this list.

Parameters:

item:

Element to be inserted.

Returns:

Returns true if the element was unique and added; otherwise false.

Overrides:

List.addItem

addItemAt

override public function addItemAt (

item:*, index:int) : Boolean

Inserts an item as a specified position.

Parameters:

item :

Element to be inserted.

index:

Position where the elements should be added.

Returns:

Returns true if the element was unique and added; otherwise false.

Overrides:

List.addItemAt

addItems

override public function addItems (

items:IList) : Boolean

Modifies original list by adding all the elements from another list that aren't already present.

Parameters:

items:

List of elements to add.

Returns:

Returns true if any elements of the specified list were unique and added; otherwise false.

Overrides:

List.addItems

addItemsAt

override public function addItemsAt (

items:IList, index:int = 0x7fffffff) : Boolean

Modifies original list by adding all the elements from another list, that aren't already present, at a specified position.

Parameters:

items:

List of elements to add.

index:

Position where the elements should be added.

Returns:

Returns true if any elements of the specified list were unique and added; otherwise false.

Overrides:

List.addItemsAt

clone

override public function clone (

) : IList

Returns a list that is an exact copy of the original list.

Returns:

Returns a list that is an exact copy of the original list.
#

Overrides:

List.clone

setItem

override public function setItem (

item:*, index:int) : *

Replaces an item at a specified position.

Parameters:

item :

The item to be stored.

index:

The index of the item to replace.

Returns:

The element previously at the specified position.
#

Throws:

Error if you try to set an item that is already contained in the list.

Overrides:

List.setItem

subList

override public function subList (

startIndex:int = 0, endIndex:int = 16777215) : IList

Returns a portion of this list.

Parameters:

startIndex:

The starting position.

endIndex :

The ending position.

Returns:

The specified portion of the list.
#

Overrides:

List.subList