+Show TOC
×Hide TOC

CasaTextField

Kind of class:	public class
Package:	org.casalib.display
Inherits from:	TextField
Implements:	IDestroyable IRemovableEventDispatcher
Version:	06/10/09
Author:	Aaron Clinger
Classpath:	org.casalib.display.CasaTextField
File last modified:	Wednesday, 10 June 2009, 11:50:09

► View source

▼ Hide source

/*
    CASA Lib for ActionScript 3.0
    Copyright (c) 2009, Aaron Clinger & Contributors of CASA Lib
    All rights reserved.
    
    Redistribution and use in source and binary forms, with or without
    modification, are permitted provided that the following conditions are met:
    
    - Redistributions of source code must retain the above copyright notice,
      this list of conditions and the following disclaimer.
    
    - Redistributions in binary form must reproduce the above copyright notice,
      this list of conditions and the following disclaimer in the documentation
      and/or other materials provided with the distribution.
    
    - Neither the name of the CASA Lib nor the names of its contributors
      may be used to endorse or promote products derived from this software
      without specific prior written permission.
    
    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
    POSSIBILITY OF SUCH DAMAGE.
*/
package org.casalib.display {
    import flash.display.Stage;
    import flash.events.Event;
    import flash.text.TextField;
    import org.casalib.core.IDestroyable;
    import org.casalib.events.IRemovableEventDispatcher;
    import org.casalib.events.ListenerManager;
    import org.casalib.util.StageReference;
    
    
    /**
        A base TextField that implements {@link IRemovableEventDispatcher} and {@link IDestroyable}.
        
        @author Aaron Clinger
        @version 06/10/09
    */
    public class CasaTextField extends TextField implements IRemovableEventDispatcher, IDestroyable {
        protected var _listenerManager:ListenerManager;
        protected var _isDestroyed:Boolean;
        
        
        /**
            Creates a new CasaTextField.
        */
        public function CasaTextField() {
            super();
            
            this._listenerManager = ListenerManager.getManager(this);
        }
        
        /**
            @exclude
        */
        override public function dispatchEvent(event:Event):Boolean {
            if (this.willTrigger(event.type))
                return super.dispatchEvent(event);
            
            return true;
        }
        
        /**
            @exclude
        */
        override public function addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void {
            super.addEventListener(type, listener, useCapture, priority, useWeakReference);
            this._listenerManager.addEventListener(type, listener, useCapture, priority, useWeakReference);
        }
        
        /**
            @exclude
        */
        override public function removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void {
            super.removeEventListener(type, listener, useCapture);
            this._listenerManager.removeEventListener(type, listener, useCapture);
        }
        
        public function removeEventsForType(type:String):void {
            this._listenerManager.removeEventsForType(type);
        }
        
        public function removeEventsForListener(listener:Function):void {
            this._listenerManager.removeEventsForListener(listener);
        }
        
        public function removeEventListeners():void {
            this._listenerManager.removeEventListeners();
        }
        
        /**
            The Stage of the display object or if the display object is not added to the display list and {@link StageReference} is defined <code>stage</code> will return the {@link StageReference#STAGE_DEFAULT default stage}; otherwise <code>null</code>.
        */
        override public function get stage():Stage {
            if (super.stage == null) {
                try {
                    return StageReference.getStage();
                } catch (e:Error) {}
            }
            
            return super.stage;
        }
        
        public function get destroyed():Boolean {
            return this._isDestroyed;
        }
        
        /**
            {@inheritDoc}
            
            Calling <code>destroy()</code> on a CASA display object also removes it from its current parent.
        */
        public function destroy():void {
            this.removeEventListeners();
            this._listenerManager.destroy();
            
            this._isDestroyed = true;
            
            if (this.parent != null)
                this.parent.removeChild(this);
        }
    }
}

A base TextField that implements IRemovableEventDispatcher and IDestroyable.

Summary

Constructor

CasaTextField

Instance properties

stage : Stage
- The Stage of the display object or if the display object is not added to the display list and StageReference is defined stage will return the default stage; otherwise null.
destroyed : Boolean

Instance methods

removeEventsForType (type:String) : void
- Removes all events of a specific type.
removeEventsForListener (listener:Function) : void
- Removes all events that report to the specified listener.
removeEventListeners : void
- Removes all event listeners.
destroy : void
- Removes any event listeners and stops all internal processes to help allow for prompt garbage collection.

Constructor

CasaTextField

public function CasaTextField (

)

Creates a new CasaTextField.

Instance properties

destroyed

public destroyed:Boolean

(read)

stage

override public stage:Stage

(read)

The Stage of the display object or if the display object is not added to the display list and StageReference is defined stage will return the default stage; otherwise null.

Instance methods

destroy

public function destroy (

) : void

Removes any event listeners and stops all internal processes to help allow for prompt garbage collection.

Always call stage before deleting last object pointer.

#

Calling destroy() on a CASA display object also removes it from its current parent.

Specified by:

IDestroyable.destroy

removeEventListeners

public function removeEventListeners (

) : void

Removes all event listeners.

Specified by:

IRemovableEventDispatcher.removeEventListeners

removeEventsForListener

public function removeEventsForListener (

listener:Function) : void

Removes all events that report to the specified listener.

Parameters:

listener:

The listener function that processes the event.

Specified by:

IRemovableEventDispatcher.removeEventsForListener

removeEventsForType

public function removeEventsForType (

type:String) : void

Removes all events of a specific type.

Parameters:

type:

The type of event.

Specified by:

IRemovableEventDispatcher.removeEventsForType